Help With

How To

Settings & Misc

Help Wurd

Using Dial Up with Broadband

Note: Looking for instructions for accessing AT&T Worldnet features through your broadband connection?

Some AT&T Worldnet internal servers (Member Services, PWP and to some extent, news and mail) were behind a firewall and only accessible from a dial up connection. Windows will always use the dial up as the default connection, thereby slowing down your surfing when using dial up and broadband (cable or DSL) together. Some of the fine denizens of the Home Networking newsgroup have both broadband connections and AT&T Worldnet accounts. They wanted to use the speed of broadband, but also needed to keep the AT&T Worldnet dialup, as that was the only way to access newsgroups, member services and PWP. So, they wrote a VBS script that sets up a routing table so when you dial in, you don't loose the surfing speed of the broadband... only the AT&T Worldnet things will go through the modem. That is no longer necessary, but we thought that we would keep this page available anyway.

Note: Due to the need to make modifications to the dial up networking connection used to connect, this script does not work on the AT&T Worldnet $14.95 and 7/7 plans as these plans do not leave a DUN connection behind to retain the changes necessary. All other plans can use the script.

Due to differences in the operating systems, there are different versions and instructions for Windows 95/98, Windows ME, and Windows 2000.

• Windows 95/98
• Windows ME
• Windows 2000/XP
• Help

Back to top

Windows 95/98

1. You may have to install the Windows Scripting host if it is not running. This can be done from the control panel, add/remove programs, Windows setup tab. In addition, if you're running the latest version of Norton Anti-Virus, make sure that the Ask me what to do option is checked if script blocking is enabled.
2. Open the Dial Up Networking folder (start, programs, accessories, communications). Right click the AT&T Worldnet connection then click Properties. On the Server types tab, click the Advanced button. Uncheck use default gateway on remote network then click OK until it is closed.
3. Move your DUN (dial up networking) connection to your desktop.
4. Click the Select text button to highlight the text. Note: Javascript must be enabled for the button to work. Then, right click the highlighted text and select Copy. Open notepad and paste the text into the blank window. Note: Be sure that wordwrap is turned OFF in notepad. Change the path to the DUN if the name and/or location in the script isn't correct. Save the script as script-win98.vbs and place it on your desktop with your DUN. They must both be in the same location.

   
   

   		'Routing Script for AT&T Worldnet for Win 9x Computers with multiple connections
   'Assumes that AT&T Worldnet IPs begin with 12
   'Change the AT&T Worldnet DUN connectoid pointed to so it does NOT use the default gateway
   
   TempFileName = "c:\Tempfile.txt"	'Any temporary location -- you pick it
   IPInString   = "IP Address"		'String to search for in IPCONFIG output
   IPNumber     = "12."			'Beginning octet WN IP address
   WorldnetDUN  = "C:\WINDOWS\Desktop\Worldnet.DUN"	'Location & name of AT&T Worldnet DUN connectoid
   
   '---------------------------------------------------------------------
   'oShell is used to run the command-line IPCONFIG program to find the IP addresses.
   set oShell=CreateObject("WScript.Shell")
   iReturnValue=oShell.run(WorldnetDUN,1,true)
   iReturnValue=oShell.run("ipconfig /batch " & TempFileName,0,true)
   
   'Open the temp file generated from the above code
   'and assign it to a variable so it can be parsed.
   Const ForReading = 1, ForWriting = 2, ForAppending = 3
   set oFileSystem = CreateObject("Scripting.FileSystemObject")
   set oFile = oFileSystem.OpenTextFile(TempFileName, ForReading)
   
   sFlag = 0
   
   'Search for IPs and check if in right domain
   Do While oFile.AtEndOfStream <> True
      sIPAddress = oFile.ReadLine	'Read line of temporary file
      If InStr(sIPAddress,IPInString) <> 0 then		'Find line start with IP Address
         ColonPos = InStr(21,sIPAddress,":")		'Find position of colon
         sIPAddress = Mid(sIPAddress,ColonPos+2)	'Extract IP portion
         'Check for correct IP
         If Trim(Left(sIPAddress,Len(IPNumber))) = IPNumber then
            sFlag = 1	'Found WN IP so set flag
            Exit Do	'and get out of the loop
         End If
      End If
   Loop       'Look for next IP
   
   If sFlag = 1 then	'Found WN IP so process route table
      oFile.Close
      set oFile=nothing
   
      'add various routes through WN dial-up
      'routes to PWP publish and ftp servers:
      iReturnValue=oShell.run("route add 204.159.38.0 MASK 255.255.255.0  " & sIPAddress, 0, true)
   
      'routes to MSWS:
      iReturnValue=oShell.run("route add 204.127.43.0 MASK 255.255.255.0  " & sIPAddress, 0, true)
      iReturnValue=oShell.run("route add 204.127.12.0 MASK 255.255.255.0  " & sIPAddress, 0, true)
   
      'routes to netnews servers:
      iReturnValue=oShell.run("route add 204.127.36.0 MASK 255.255.255.0  " & sIPAddress, 0, true)
   
      'routes to postoffice server:
      iReturnValue=oShell.run("route add 204.127.5.0 MASK 255.255.255.0  " & sIPAddress, 0, true)
   
      'route to SMTP server
      iReturnValue=oShell.run("route add 204.127.8.0 MASK 255.255.255.0  " & sIPAddress, 0, true)
   
      'route to WURD server
      iReturnValue=oShell.run("route add 204.127.237.0 MASK 255.255.255.0 " & sIPAdress, 0, true)
   
      'routes to home page
      iReturnValue=oShell.run("route add 135.145.0.0 MASK 255.255.0.0  " & sIPAddress, 0, true)
   
      'Delete temporary file.
      oFileSystem.DeleteFile TempFileName,true
   
      'Cleanup
      set oTXTFile    = nothing
      set oFileSystem = nothing
      set oShell      = nothing
   
      MsgBox "AT&T Worldnet access routed to " & sIPAddress
   
   else
      MsgBox "Failed to find AT&T Worldnet IP Address of form 12.xx.xx.xx"
   end if

5. Now click the script to connect to AT&T Worldnet Service.

Back to top

Windows ME

Note: Due to the way ME works, you must first connect with the Dial Up Networking connection then run the script.

1. You may have to install the Windows Scripting host if it is not running. This can be done from the control panel, add/remove programs, Windows setup tab. In addition, if you're running the latest version of Norton Anti-Virus, make sure that the Ask me what to do option is checked if script blocking is enabled.
2. Open the dial up networking folder (start, programs, accessories, communications). Right click the AT&T Worldnet connection then click Properties. On the Server types tab, click the Advanced button. Uncheck use default gateway on remote network then click OK until it is closed.
3. Click the Select text button to highlight the text. Note: Javascript must be enabled for the button to work. Then, right click the highlighted text and select Copy. Open notepad and paste the text into the blank window. Note: Be sure that wordwrap is turned OFF in notepad. Save the script as script-winME.vbs and place it on your desktop.
   
   

   		
   'Routing Script for AT&T Worldnet for Win ME Computers with multiple connections
   'Assumes that AT&T Worldnet IPs begin with 12
   TempFileName="c:\Tempfile.txt"		'Any temporary location
   IPAddressToPost=2		'Run IPCONFIG from a DOS prompt...which IP address is the one you want?
   
   
   IPStringInFile="IP Address. . . . . . . . . : "
   
   '---------------------------------------------------------------------
   
   
   'oShell is used to run the command-line IPCONFIG program to find the IP addresses.
   set oShell=CreateObject("WScript.Shell")
   iReturnValue=oShell.run("ipconfig /batch " & TempFileName,1,true)
   
   'Open the file generated from the above code and assign it to a variable
   'so it can be parsed.
   Const ForReading = 1, ForWriting = 2, ForAppending = 3
   set oFileSystem = CreateObject("Scripting.FileSystemObject")
   set oFile = oFileSystem.OpenTextFile(TempFileName, ForReading)
   sIPString=oFile.ReadAll
   oFile.Close
   set oFile=nothing
   
   'Look for the correct IP address, since computers can have multiple ones.
   nIPAddressLocation=1 'Start at the very beginning...
   for nMoveThroughIPAddresses = 1 to IPAddressToPost
   	nIPAddressLocation=InStr(nIPAddressLocation,sIPString,IPStringInFile)
   	nIPAddressLocation=nIPAddressLocation + Len(IPStringInFile)
   next
   
   'OK, we found the IP address, now make sure we don't grab anything else
   'besides the actual IP address (we don't want the trailing characters)
   nLastDigitAtLocation=15
   for nCounter = 0 to 15
   	sThisChar=Mid(sIPString,nIPAddressLocation+nCounter,1)
   	if sThisChar = vbLf or sThisChar = vbCr then
   		if nCounter < nLastDigitAtLocation then
   			nLastDigitAtLocation = nCounter
   		end if
   	end if
   next
   
   'Put the IP address into the sIPAddress string for use later.
   sIPAddress=Mid(sIPString,nIPAddressLocation,nLastDigitAtLocation)
   
   rem add various routes through WN dial-up
   rem routes to PWP publish and ftp servers:
   iReturnValue=oShell.run("route add 204.159.38.0 MASK 255.255.255.0  " & sIPAddress, 1, true)
   rem routes to MSWS and WN homepage:
   iReturnValue=oShell.run("route add 204.127.43.0 MASK 255.255.255.0  " & sIPAddress, 1, true)
   iReturnValue=oShell.run("route add 204.127.12.0 MASK 255.255.255.0  " & sIPAddress, 1, true)
   rem routes to netnews servers:
   iReturnValue=oShell.run("route add 204.127.36.0 MASK 255.255.255.0  " & sIPAddress, 1, true)
   rem routes to postoffice server:
   iReturnValue=oShell.run("route add 204.127.5.0 MASK 255.255.255.0  " & sIPAddress, 1, true)
   rem routes to mailhost server:
   iReturnValue=oShell.run("route add 204.127.8.0 MASK 255.255.255.0  " & sIPAddress, 1, true)
   
   
   'Delete temporary file.
   oFileSystem.DeleteFile TempFileName,true
   
   'Cleanup
   set oTXTFile=nothing
   set oFileSystem=nothing
   set oShell = nothing
   
   MsgBox "AT&T Worldnet access routed to " & sIPAddress
   

4. Connect to AT&T Worldnet Service using the dial up networking connection and then click the script to run it.

Back to top

Windows 2000/XP

Note: You will need to find your AT&T Worldnet Service account information.

1. You may have to install the Windows Scripting host if it is not running. This can be done from the control panel, add/remove programs, Windows setup tab. In addition, if you're running the latest version of Norton Anti-Virus, make sure that the Ask me what to do option is checked if script blocking is enabled.
2. Open the Dial up networking connection, but do not connect. Click the Properties button, then click the Networking tab. Click once on the listing for Internet Protocol(TCP/IP) then click the Properties button. On the window that pops up, click the Advanced button and uncheck use default gateway on remote network. Click OK until all the DUN windows are closed.
3. Click the Select text button to highlight the text. Note: Javascript must be enabled for the button to work. Then, right click the highlighted text and select Copy. Open notepad and paste the text into the blank window. Note: Be sure that wordwrap is turned OFF in notepad. Put in your username and password from your account.txt or acctinfo.htm file. Also, put in the name of your AT&T Worldnet connection. Save the script as script-win2k.vbs and place it on your desktop.
   
   

   		
   'Routing Script for AT&T Worldnet for Win 2K/XP Computers with multiple connections
   'Assumes that AT&T Worldnet IPs begin with 12
   TempFileName="c:\ips.txt"    'Any temporary location
   IPInString = "IP Address"    'String to search for
   IPNumber = "12."             'Beginning of IP to search for. 
   ConnectionName = "Worldnet"  'the name of your Worldnet connectoid
   UserName = "number@worldnet.att.net"    'replace with your NETWORK ID
   Password = "xxxxxxxxxxxxxxxx" 'replace with your NETWORK PASSWORD
   
   '---------------------------------------------------------------------
   'Shell is used to run the command-line IPCONFIG program to find the IP addresses.
   Set oShell = CreateObject("WScript.Shell")
   'Dial the connection
   oShell.Run "%comspec% /c rasdial.exe " & ConnectionName & " " & UserName & " " & Password,2,true 
   'Capture IPs of connections to temporary file
   oShell.Run "%comspec% /c ipconfig.exe > " & TempFileName,2,true  'line 10
   'Open the file generated from the above code and assign it to a variable
   'so it can be parsed.
   Const ForReading = 1, ForWriting = 2, ForAppending = 3
   set oFileSystem = CreateObject("Scripting.FileSystemObject")
   set oFile = oFileSystem.OpenTextFile(TempFileName, ForReading)
   sFlag = 0
   'Search for IPs and check if in right domain
   Do While oFile.AtEndOfStream <> True
     	sIPAddress = oFile.ReadLine			'Read line of temporary file
   	If Instr(sIPAddress,IPInString) <>0  then	'Find line start with IP Address
   		ColonPos = Instr(21,sIPAddress,":") 	'Find position of colon
   		sIPAddress = Mid(sIPAddress,ColonPos+2)	'Extract IP portion
   		If Trim(Left(sIPAddress,Len(IPNumber))) = IPNumber then 'Check of right IP
   			sFlag = 1  'Found good IP so set flag
   			exit do
   		End If
   	End If	
   Loop							'Look for next IP
   If sFlag = 1 then   'Found good IP so process route table
   oFile.Close
   set oFile=nothing
   
   rem add various routes through WN dial-up
   
   rem route to PWP publish and ftp servers:
   oShell.run "%comspec% /c route add 204.159.38.0 MASK 255.255.255.0  " & sIPAddress, 0, true
   '
   rem route to netnews servers:
   oShell.run "%comspec% /c route add 204.127.36.0 MASK 255.255.255.0  " & sIPAddress, 0, true
   '
   rem route to postoffice servers:
   oShell.run "%comspec% /c route add 204.127.5.0 MASK 255.255.255.0  " & sIPAddress, 0, true
   '
   rem route to SMTP servers
   oShell.run "%comspec% /c route add 204.127.8.0 MASK 255.255.255.0  " & sIPAddress, 0, true
   '
   rem routes to WN home page, MSWS
   oShell.run "%comspec% /c route add 204.127.12.0 MASK 255.255.255.0  " & sIPAddress, 0, true
   oShell.run "%comspec% /c route add 204.127.43.0 MASK 255.255.255.0  " & sIPAddress, 0, true
   
   rem End of routes
   
   'Delete temporary file.
   oFileSystem.DeleteFile TempFileName,true
   
   'Cleanup
   set oTXTFile=nothing
   set oFileSystem=nothing
   set oShell = nothing
   
   end if
   		

4. Click the script to connect to AT&T Worldnet Service.

Back to top

Help

If you have any questions or encounter any difficulties with this script using the copy and paste method shown above, try downloading the script by right clicking on the appropriate link below, selecting Save As and save the file to your desktop with a vbs extension. If you continue to have problems, please post to the worldnet.users.home-networking newsgroup for assistance.

• Windows 95/98
• Windows ME
• Windows 2000/XP

Note: If you're running the latest version of Norton Anti-Virus, you will have to disable the setting to stop vbs scripts from running for this to work.

Back to top

Did you find this Web page useful?
					Please tell us why...
Note: We are unable to answer questions submitted through this form. All submissions are automatically tabulated and comments are sent to the Web design team, not to support personnel. Please try AT&T Worldnet Help if you need further help.